WIN8激活信息备份

ghost的方法就不用说了

直接备份激活信息:

1、win8激活后,备份以下路径文件夹 C:WindowsSystem32sppstore 文件夹(内含隐藏文件)

2、重装系统,记住必须是与激活时相同的版本(新系统的硬件信息,用户名、密码、计算机名等应与上述备份所属系统的设置一致,不一致的没试过)

3、管理员身份运行cmd 输入slmgr -upk回车(清除Key信息)

4、Win+R 运行 msconfig-boot-safe mode(设置安全模式启动,选择重启)

5、在safe mode下,管理员身份运行cmd 输入net stop sppsvc(关闭Software Protection)

6、在C:WindowsSystem32spp 文件夹下,用已备份的store文件夹覆盖该目录下的store文件夹;

7、Win+R, msconfig-boot-去掉safe mode选勾,正常启动。

硬盘分区计算原理

追求所谓完美分区的可以研究一下!
一般公式为:分区大小=(分区大小-1)×4+1024×分区大小
     如果按照以上硬盘分区公式(X-1)*4+1024*X=Y 其中X就是你想要得到的整数分区的数值,单位是G,Y是你分区时应该输入的数字,单位是M。
按照这样的计算方法:
5G=5136MB
10G=10276MB
15G=15416MB
20G=20556MB
30G=30836MB
40G=41116MB
30G以内,输入上面的数据,如10G你输入10276,在Windows资源管理器里面显示的刚好10.00GB,而在管理工具-磁盘管理界面显示就是10.04GB,如果是40G你输入41116,那么在Windows资源管理器里面显示的刚好40.01GB。
因此上面的计算公式还不是很准确。
最精确硬盘分区的算法如下(来自网络):
硬盘一般有255磁头,63扇区,故每柱面大小为:
512byte x 255 x 63=8225280bytes =7.84423828125 MB
如果要分40GB,那么要40x1024MB=40960MB
需要柱面数为40960÷7.84423828125=5221.66
取整数既为5222个柱面
应分M数为5222×7.84423828125=40962.6123046875MB
不管小数点后面几位都进1,也就是40963MB,windows就认为是40GB了。
这个方法NTFS和FAT32通用。
下面附10GB到200GB整10GB递增的精确计算结果:
10GB = 10245MB
20GB = 20482MB
30GB = 30726MB
40GB = 40963MB
50GB = 51208MB
60GB = 61444MB
70GB = 71681MB
80GB = 81926MB
90GB = 92162MB
100GB = 102407MB
110GB = 112644MB
120GB = 122888MB
130GB = 133125MB
140GB = 143362MB
150GB = 153606MB
160GB = 163843MB
170GB = 174088MB
180GB = 184324MB
190GB = 194561MB
     此精确分区结果,在管理工具-磁盘管理界面,和Windows资源管理器里面显示的是整数,10G就是10.00GB,20G就是20.00GB,40G就是40.00GB。

修改WINDOWS右键发送到菜单

虽然很多优化软件可以修改windows右键发送到菜单,但是总有一些人不喜欢装这些乱七八糟的软件.比如我,自己手动修改才觉得靠谱!

1.在Windows 9x/Me系统里面,这个文件夹的位置为“C:WindowsSendTo”.

2.在Windows 2000/XP则为“C:Documents and Settings用户名SendTo”。

3.从Vista时代开始到现在的Windows7,“发送到路径则变成了 C:/user/用户名/AppData/Roaming/Microsoft/Windows/SendTo/

ps:具体路径请按自己的实际情况修改!也许你的系统盘不是C,也许你的用户目录不在系统盘……如果看不懂,那还是用那些优化的软件比较好,没必要为这点事纠结!

WIN7批处理创建虚拟无线局域网

本脚本仅支持WIN7,需要以管理员权限运行,电脑需要有无线网卡,开启后可创建虚拟的路由,可以设置共享主机的网络连接.(创建局域网后,需要手动共享电脑的网络连接以让其他电脑也能上网,否则就只能内部联网,如玩局域网游戏,虽然手动开启共享的步骤很简单,脚本操作时也有说明,但是如果是在不会,也可以使用一款名为Connectify的软件,具体请百度)

@echo off
title 虚拟无线网卡
color 8A

::~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
::以下为可修改参数(可修改各项等号后的默认值)
set Dssid=Virtual-WiFi
::注释,Virtual-WiFi为默认的网络名称,建议名称为英文,可获得更多设备的支持
set Dkey=987654321
::注释,987654321为默认的密码,密码必须8位以上
set DkeyUsage=persistent
::注释,persistent表示用户连接本网络后永久保存密码,temporary表示用户断开网络后删除密码,即每次连接均需要输入密码
set auto=1
::注释,1表示正常模式,0表示直接以默认参数自动设置
set log=1
::注释 1表示记录路由连接信息,0表示不记录(进入显示路由信息界面后开始记录)
set timer=30
::注释 此参数表示显示路由信息时自动刷新的时间间隔(秒)
::~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

::以下为固定内容,如不了解请勿修改!!

:check
netsh wlan start hostednetwork>nul
if errorlevel 1 goto error

:begin
set key=0
set ssid=0
cls

echo 虚拟无线热点创建(WIN7专用)
echo 
echo 注意:
echo 使用本程序前需先启用无线网络!!
echo 当前默认网络名为:%Dssid%
echo 当前默认密码为:%Dkey%
if %auto%==0 goto fast
echo 
echo 请选择模式!!(输入选项的数字编号)
echo 1.刷新配置信息(设备无法获取IP时可尝试此项)
echo 2.显示当前路由配置及已连接的设备信息
echo 3.修改当前网络密码
echo 4.快速开启模式(使用默认网络名称和密码快速设置)
echo 5.自定义模式(用户手动输入网络名称以及密码)
echo 6.开启虚拟无线热点(用于已经进行过名称密码设置后的快速开启)
echo 7.关闭虚拟无线热点
echo 8.编辑默认参数
echo 9.退出

choice /c 123456789 /m 请输入你的选择
if errorlevel 9 goto end
if errorlevel 8 goto edit
if errorlevel 7 goto close
if errorlevel 6 goto open
if errorlevel 5 goto normal
if errorlevel 4 goto fast
if errorlevel 3 goto chkey
if errorlevel 2 goto info
if errorlevel 1 goto refresh
goto begin


:refresh
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
netsh wlan refresh hostednetwork key
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 操作已结束,按任意键返回!!
pause>nul
goto begin


:info
cls
echo 路由信息检测 %date% %time:~0,-3%
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
netsh wlan show hostednetwork
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 1.立即刷新信息 2.返回主菜单
CHOICE /T %timer% /c 12 /CS /D 1 /M 路由信息将在%timer%秒内自动刷新!
if errorlevel 2 goto begin
if errorlevel 1 goto writelog
goto begin

:writelog
if %log%==0 goto info
echo %date% %time:~0,-3%>>%~dp0/路由信息记录.txt
netsh wlan show hostednetwork|findstr /c:" 客户端数">>%~dp0/路由信息记录.txt
netsh wlan show hostednetwork|findstr /c:"已经过身份验证">>%~dp0/路由信息记录.txt
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~>>%~dp0/路由信息记录.txt
goto info


:chkey
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 输入密码(密码必须8位以上!直接回车则使用默认密码%Dkey%)
set /p key=" "
if %key%==0 echo 已使用默认密码%Dkey%
if %key%==0 set key=%Dkey%
netsh wlan set hostednetwork key=%key%
netsh wlan refresh hostednetwork key
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 操作已结束,按任意键返回!!
pause>nul
goto begin

:normal
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 自定义模式,缺省默认参数为:网络名称%Dssid%,密码%Dkey%
echo 输入网络名称(直接回车则使用默认网络名称%Dssid%)
echo 网络名称尽量使用英文以获得更多的设备支持
set /p ssid=" "
if %ssid%==0 echo 已使用默认网络名称%Dssid%
if %ssid%==0 set ssid=%Dssid%
echo 
echo 输入密码(密码必须8位以上!直接回车则使用默认密码%Dkey%)
set /p key=""
if %key%==0 echo 已使用默认密码%Dkey%
if %key%==0 set key=%Dkey%
echo 
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 网络名称%ssid%,密码%key%
echo 正在设置网络模式......
netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%key% keyUsage=%DkeyUsage%
::注释,命令参数解释,可在上命令中对应参数处修改!
::注释,mode=allow:承载网络模式设置为开启,disallow为关闭
echo 正在启用网络......
netsh wlan start hostednetwork
goto share

:fast
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 快速模式,网络名称%Dssid%,密码%Dkey%
echo 正在设置网络模式......
netsh wlan set hostednetwork mode=allow ssid=%Dssid% key=%Dkey% keyUsage=%DkeyUsage%
echo 正在启用网络......
netsh wlan start hostednetwork
goto share

:share
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 如需要共享internet连接,请按以下步骤操作后,按任意键继续!!
echo 如不需要共享internet连接,仅作为局域网使用,可直接按任意键继续!!
echo 以下操作仅需一次,下次开启时可直接按任意键继续!!
echo 1. 打开 "网络和共享中心"
echo 2. 选择 "更改适配器设置"
echo 此时记住显示为Microsoft Virtual WiFi Miniport Adapter的连接的网络名称,
echo 一般是 无线网络连接 2
echo 3. 右键单击已连接intetnet的网络,选择 "属性",再选择 "共享" 标签
echo 4. 勾选 "允许其他用户通过此计算机的Internet连接来连接"
echo 5. 在下拉框中选择 "无线网络连接2",确定
echo 根据个人情况可能有所不同,具体名称以适配器中记住的名称为准!
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 操作已结束,按任意键返回!!
pause>nul
goto begin

:open
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 正在开启虚拟无线热点......
netsh wlan start hostednetwork
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 操作已结束,按任意键返回!!
pause>nul
goto begin

:close
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 正在关闭虚拟无线热点......
netsh wlan stop hostednetwork
echo 正在移除虚拟网卡......
netsh wlan set hostednetwork mode=disallow
echo ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo 操作已结束,按任意键返回!!
pause>nul
goto begin

:edit
start notepad %~0
exit

:error
echo .
echo . 环境测试失败
echo .
echo . 可能原因:
echo .
echo . 1.未获取权限,右键选择本程序以管理员身份运行
echo . 2.使用系统不是WIN7(XP不支持本功能)
echo .
echo . 按任意键退出!
pause>nul
exit

:end
exit

下载:虚拟无线网络